TKSoft-Online

Problemstellung:

Wie kann ich die Version einer MDB-Datei ermitteln?

Folgenden Code in öffentliches Modul kopieren:

Public Function MDBVersionFromFile(strTestDB As String, Optional strPasswort As String = "") As String
' Für Versionen 1.0 und 2.0 wird die Jet Version verwendet, für Versionen
' darüber die AccessVersion property.
' Referenz setzen auf Microsoft DAO 3.6 Library

    Dim wrk As DAO.Workspace
    Dim db As DAO.Database
    Dim strPWD As String

    ' Prüfung ob DB-Kennwort angegeben wurde
    strPWD = ";pwd=" & strPasswort

    Set wrk = CreateWorkspace("CheckVersion", "admin", "", dbUseJet)
    On Error Resume Next
    Set db = wrk.OpenDatabase(strTestDB, False, False, strPWD)
    If Err.Number = 0 Then
        Select Case db.Version
            Case "12.0"
                MDBVersionFromFile = "Access 2007/2010"
            Case "3.0", "4.0"
                Select Case db.Properties("AccessVersion")
                    Case "09.50"
                        MDBVersionFromFile = "Access XP/2003"
                    Case "08.50"
                        MDBVersionFromFile = "Access 2000"
                    Case "07.53"
                        MDBVersionFromFile = "Access 97"
                    Case "06.68"
                        MDBVersionFromFile = "Access 95"
                    Case Else
                        MDBVersionFromFile = "AccessVersion " & db.Properties("AccessVersion")
                End Select
            Case "2.0"
                MDBVersionFromFile = "Access 2.0"
            Case "1.0"
                MDBVersionFromFile = "Access 1.x"
            Case Else
                MDBVersionFromFile = "Jet Version " & db.Version
        End Select
    ElseIf Err.Number = 3045 Then
        MDBVersionFromFile = "Datei in Gebrauch"
    ElseIf Err.Number = 3033 Then
        MDBVersionFromFile = "Keine Zugriffserlaubnis"
    Else
        MDBVersionFromFile = "Unbekannt"
    End If
    If Not db Is Nothing Then
        db.Close
        Set db = Nothing
    End If
    wrk.Close
    Set wrk = Nothing

End Function

Aufruf:

 MsgBox MDBVersionFromFile("C:\Test\test.mdb")

Ergebnis: